Script para enviar alertas por falta de inventario de hardware

En el post anterior veíamos como generar un reporte que nos liste las computadoras que en determinada cantidad de días no enviaron su inventario de hardware al servidor.
En esta ocasión veremos como armar un sencillo script que envía un correo con el reporte que hicimos antes.
El mismo script puede usarse para enviar cualquier otro reporte de SCCM. Si además combinamos este script con una tarea programada de Windows podremos tener alertas periódicas con datos sobre las computadoras que administramos con SCCM.

Este es el script:

Remitente="correo del remitente"
Destinatario="correo del destinatario"
Asunto= "Asunto del correo"

'1 para SMTP local, 2 para SMTP remoto
TipoSMTP = 2 

'Dirección del servidor SMTP
SMTP = "dirección o IP de nuestro servidor SMTP"

'Puerto SMTP utilizado por nuestro servidor
Puerto = 25

'URL del reporte que enviaremos por correo
Reporte = "http://hellboy/Reportes/Report.asp?ReportID=431&Dias=2&SortRs1Col=3&SortRs1Dir=2"


'************************Envío del correo***************************************

Set objMessage = CreateObject("CDO.Message")
Set Stm = CreateObject("ADODB.Stream")


objMessage.Subject = Asunto
objMessage.From = Remitente
objMessage.To = Destinatario

objMessage.Configuration.Fields.Item _
("http://schemas.microsoft.com/cdo/configuration/sendusing") = TipoSMTP
'Servidor SMTP
objMessage.Configuration.Fields.Item _
("http://schemas.microsoft.com/cdo/configuration/smtpserver") = SMTP
'Puerto SMTP
objMessage.Configuration.Fields.Item _
("http://schemas.microsoft.com/cdo/configuration/smtpserverport") = Puerto

objMessage.CreateMHTMLBody(Reporte)
'ObjMessage.AddAttachment (Adjunto)
objMessage.Configuration.Fields.Update

On Error Resume Next  
objMessage.Send
If not(Err.Number = 0) Then  
    MsgBox Err.Description, vbCritical, " Error al enviar el mail "  
End If

Así de simple.
En este caso el script envía el reporte que creamos en nuestro anterior post (el que buscaba computadoras sin inventario de hardware reciente), y le pasa como parámetro (dentro de la URL) la cantidad de días límite para la búsqueda (en este caso 2 días).
Para enviar cualquier otro reporte basta con ejecutarlo en el SCCM y copiar la URL dentro del script.
Para que las alertas lleguen periodicamente basta con crear una tarea programada que ejecute el script.

Saludos
Franco